Library iris.heap_lang.wp_tactics

From iris.algebra Require Export upred_tactics.
From iris.heap_lang Require Export tactics derived.
Import uPred.

Ltac wp_bind K :=
  lazymatch eval hnf in K with
  | [] ⇒ idtac
  | _ ⇒ etrans; [|fast_by apply (wp_bind K)]; simpl
  end.

Ltac wp_done :=
  match goal with
  | |- Closed _ _ ⇒ solve_closed
  | |- is_Some (to_val _) ⇒ solve_to_val
  | |- to_val _ = Some _ ⇒ solve_to_val
  | |- language.to_val _ = Some _ ⇒ solve_to_val
  | _ ⇒ fast_done
  end.

Ltac wp_strip_pvs :=
  lazymatch goal with
  | |- _ ⊢ |={?E}=> _ ⇒
    etrans; [|apply pvs_intro];
    match goal with |- _ ⊢ wp E _ _ ⇒ simpl | _ ⇒ fail end
  end.

Ltac wp_value_head := etrans; [|eapply wp_value_pvs; wp_done]; lazy beta.

Ltac wp_strip_later := idtac.
Ltac wp_seq_head :=
  lazymatch goal with
  | |- _ ⊢ wp ?E (Seq _ _) ?Q ⇒
    etrans; [|eapply wp_seq; wp_done]; wp_strip_later
  end.

Ltac wp_finish := intros_revert ltac:(
  rewrite /= ?to_of_val;
  try wp_strip_later;
  repeat lazymatch goal with
  | |- _ ⊢ wp ?E (Seq _ _) ?Q ⇒
     etrans; [|eapply wp_seq; wp_done]; wp_strip_later
  | |- _ ⊢ wp ?E _ ?Q ⇒ wp_value_head
  | |- _ ⊢ |={_}=> _ ⇒ wp_strip_pvs
  end).

Tactic Notation "wp_value" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    wp_bind K; wp_value_head) || fail "wp_value: cannot find value in" e
  | _ ⇒ fail "wp_value: not a wp"
  end.

Tactic Notation "wp_rec" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with App ?e1 _ ⇒


    wp_bind K; etrans; [|eapply wp_rec; wp_done]; simpl_subst; wp_finish
end) || fail "wp_rec: cannot find 'Rec' in" e
  | _ ⇒ fail "wp_rec: not a 'wp'"
  end.

Tactic Notation "wp_lam" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with App ?e1 _ ⇒

    wp_bind K; etrans; [|eapply wp_lam; wp_done]; simpl_subst; wp_finish
end) || fail "wp_lam: cannot find 'Lam' in" e
  | _ ⇒ fail "wp_lam: not a 'wp'"
  end.

Tactic Notation "wp_let" := wp_lam.
Tactic Notation "wp_seq" := wp_let.

Tactic Notation "wp_op" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    lazymatch eval hnf in e' with
    | BinOp LtOp _ _ ⇒ wp_bind K; apply wp_lt; wp_finish
    | BinOp LeOp _ _ ⇒ wp_bind K; apply wp_le; wp_finish
    | BinOp EqOp _ _ ⇒ wp_bind K; apply wp_eq; wp_finish
    | BinOp _ _ _ ⇒
       wp_bind K; etrans; [|eapply wp_bin_op; try fast_done]; wp_finish
    | UnOp _ _ ⇒
       wp_bind K; etrans; [|eapply wp_un_op; try fast_done]; wp_finish
    end) || fail "wp_op: cannot find 'BinOp' or 'UnOp' in" e
  | _ ⇒ fail "wp_op: not a 'wp'"
  end.

Tactic Notation "wp_proj" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with
    | Fst _ ⇒ wp_bind K; etrans; [|eapply wp_fst; wp_done]; wp_finish
    | Snd _ ⇒ wp_bind K; etrans; [|eapply wp_snd; wp_done]; wp_finish
    end) || fail "wp_proj: cannot find 'Fst' or 'Snd' in" e
  | _ ⇒ fail "wp_proj: not a 'wp'"
  end.

Tactic Notation "wp_letp" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with
    | Letp _ _ _ _ ⇒
      wp_bind K;
      etrans; [|eapply wp_letp]; wp_finish
    end) || fail "wp_letp: cannot find 'Letp' in" e
  | _ ⇒ fail "wp_letp: not a 'wp'"
  end.

Tactic Notation "wp_if" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with
    | If _ _ _ ⇒
      wp_bind K;
      etrans; [|eapply wp_if_true || eapply wp_if_false]; wp_finish
    end) || fail "wp_if: cannot find 'If' in" e
  | _ ⇒ fail "wp_if: not a 'wp'"
  end.

Tactic Notation "wp_match" :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match eval hnf in e' with
    | Case _ _ _ ⇒
      wp_bind K;
      etrans; [|first[eapply wp_match_inl; wp_done|eapply wp_match_inr; wp_done]];
      simpl_subst; wp_finish
    end) || fail "wp_match: cannot find 'Match' in" e
  | _ ⇒ fail "wp_match: not a 'wp'"
  end.

Tactic Notation "wp_focus" open_constr(efoc) :=
  lazymatch goal with
  | |- _ ⊢ wp ?E ?e ?Q ⇒ reshape_expr e ltac:(fun K e' ⇒
    match e' with
    | efoc ⇒ unify e' efoc; wp_bind K
    end) || fail "wp_focus: cannot find" efoc "in" e
  | _ ⇒ fail "wp_focus: not a 'wp'"
  end.